# Sicherstellen, dass ein TextGrid markiert ist;
# Wenn nicht, bricht das Skript mit einer Fehlermeldung ab
textgrid$ = selected$ ("TextGrid")

# Festlegen, welches TextGrid-tier ausgewertet werden soll
tier_nr = 1

# Überschrift und Kopfzeile in das Info-Fenster schreiben
writeInfoLine: "Auswertung von ", textgrid$
appendInfoLine: ""
appendInfoLine: "Nr.", tab$, "Dauer (in ms)", tab$, "Label"
appendInfoLine: ""

# Anzahl der Intervalle abfragen
noi = Get number of intervals: tier_nr
# Die folgende Schleife (for ... endfor) springt
# von Intervall zu Intervall
for zaehler to noi
    # Startzeitpunkt des aktuelen Intervalls abfragen
    sp = Get start point: tier_nr, zaehler
    # Endzeitpunkt des aktuelen Intervalls abfragen
    ep = Get end point: tier_nr, zaehler
    # Dauer berechnen (ep-sp), in Millisekunden konvertieren
    # (*1000) und Nachkommastellen entfernen (round)
    dur = round((ep-sp)*1000)
    # Label des aktuelen Intervalls abfragen
    label$ = Get label of interval: tier_nr, zaehler
    # neue Zeile in das Info-Fenster schreiben
    appendInfoLine: zaehler, tab$, tab$, dur, tab$, tab$, label$
    # Zum nächsten Intervall springen oder Schleife beenden
endfor