form Bitte füllen Sie das folgende Formular aus
    comment Geben Sie den Pfad zu Ihren Wav-Dateien an.
    sentence Pfad_zu_den_Dateien /Users/jm/Tmp/praatdemo
    comment Welche Art von Spektrogramm anzeigen?
    optionmenu Spektrogramm 1
        option Breitband
        option Schmalband
endform

if spektrogramm = 1
    windowLength = 0.005
else
    windowLength = 0.03
endif

Create Strings as file list: "DateiListe", pfad_zu_den_Dateien$ + "/*.wav"
anzahlDateien = Get number of strings

clearinfo

for dateiNr from 1 to anzahlDateien
    selectObject: "Strings DateiListe"
    dateiName$ = Get string: dateiNr
    Read from file: pfad_zu_den_Dateien$ + "/" + dateiName$
    objektName$ = selected$ ("Sound")
    To TextGrid: "Vokale Mittelpunkte", "Mittelpunkte"
    selectObject: "Sound " + objektName$
    plusObject: "TextGrid " + objektName$
    View & Edit
    editor: "TextGrid " + objektName$
    Show analyses: "yes", "no", "no", "no", "no", 60
    Spectrogram settings: 0, 8000, windowLength, 50
    pauseScript: "Nächste Datei laden?"
    Close
    selectObject: "TextGrid " + objektName$
    textGrid$ = pfad_zu_den_Dateien$ + "/" + objektName$ + ".TextGrid"
    if fileReadable (textGrid$)
        appendInfoLine: "Achtung!"
        appendInfoLine: "Die Datei 'textGrid$' existiert bereits."
        appendInfoLine: "Das TextGrid 'objektName$' wurde"
        appendInfoLine: "nicht gespeichert."
    else
        Save as text file: textGrid$
        removeObject: "Sound " + objektName$, "TextGrid " + objektName$
    endif
endfor

removeObject: "Strings DateiListe"